Kalkulator Perhitungan Pajak Progresif PPh 21 Otomatis di Excel dengan VBA

Mengelola perhitungan PPh 21 sering kali menjadi tantangan tersendiri, apalagi jika harus menghitungnya secara manual dan berulang untuk setiap karyawan. Excel hadir sebagai solusi praktis, dan ketika digabungkan dengan fitur VBA, kamu bisa membuat kalkulator perhitungan pajak progresif PPh 21 yang bekerja secara otomatis, akurat, dan sesuai regulasi terbaru.

Dalam artikel ini, kamu akan mempelajari cara membuat kalkulator perhitungan pajak progresif PPh 21 di Excel dengan memanfaatkan User Defined Function (UDF). Kalkulator ini dapat digunakan untuk perhitungan pajak tahunan, bulanan, hingga final berdasarkan karakteristik penghasilan pegawai.

Apa Itu Kalkulator Perhitungan Pajak Progresif PPh 21?

Kalkulator perhitungan pajak progresif PPh 21 adalah alat bantu digital berbasis Excel yang dirancang untuk menghitung besaran pajak penghasilan (PPh) Pasal 21 karyawan berdasarkan tarif pajak progresif yang ditentukan oleh Direktorat Jenderal Pajak.

Tarif pajak progresif artinya semakin tinggi penghasilan seseorang, maka persentase pajak yang dikenakan juga meningkat. Oleh karena itu, penting menggunakan kalkulator otomatis agar tidak salah dalam mengelompokkan lapisan penghasilan.

Tabel Tarif Pajak Progresif PPh 21 Terbaru

Perhitungan pajak pada kalkulator ini mengacu pada lapisan PKP (Penghasilan Kena Pajak) sebagai berikut:

Dengan kalkulator perhitungan pajak progresif PPh 21 otomatis, lapisan-lapisan ini akan dihitung secara cerdas dan bertingkat sesuai jumlah PKP.

Script VBA Kalkulator Perhitungan Pajak Progresif PPh 21

Option Explicit

Function HitungPPh21(JenisPemotongan As String, PenghasilanBruto As Double, Status As String, PremiAsuransi As Double) As Double
    Select Case UCase(JenisPemotongan)
        Case "PPH 21 TAHUNAN (A1/A2)"
            HitungPPh21 = HitungPPh21Tahunan(PenghasilanBruto, Status, PremiAsuransi)
        Case "PPH 21 BULANAN"
            HitungPPh21 = HitungPPh21Tahunan(PenghasilanBruto * 12, Status, PremiAsuransi * 12) / 12
        Case "PPH 21 FINAL"
            HitungPPh21 = PenghasilanBruto * 0.005
        Case Else
            HitungPPh21 = 0
    End Select
End Function

Function HitungPPh21Tahunan(PenghasilanBruto As Double, Status As String, PremiAsuransi As Double) As Double
    Dim PTKP As Double, PKP As Double, Pajak As Double, BiayaJabatan As Double

    ' 1. Hitung biaya jabatan
    BiayaJabatan = Application.WorksheetFunction.Min(PenghasilanBruto * 0.05, 6000000)

    ' 2. Tentukan PTKP berdasarkan status
    Select Case UCase(Status)
        Case "TK/0": PTKP = 54000000
        Case "K/0": PTKP = 58500000
        Case "K/1": PTKP = 63000000
        Case "K/2": PTKP = 67500000
        Case "K/3": PTKP = 72000000
        Case Else: PTKP = 54000000
    End Select

    ' 3. Hitung PKP dan bulatkan ke ribuan
    PKP = Application.WorksheetFunction.Max(PenghasilanBruto - BiayaJabatan - PremiAsuransi - PTKP, 0)
    PKP = Application.WorksheetFunction.Floor(PKP, 1000)

    ' 4. Hitung pajak secara progresif
    Pajak = 0
    If PKP > 5000000000# Then
        Pajak = Pajak + (PKP - 5000000000#) * 0.35
        PKP = 5000000000#
    End If
    If PKP > 500000000 Then
        Pajak = Pajak + (PKP - 500000000) * 0.3
        PKP = 500000000
    End If
    If PKP > 250000000 Then
        Pajak = Pajak + (PKP - 250000000) * 0.25
        PKP = 250000000
    End If
    If PKP > 60000000 Then
        Pajak = Pajak + (PKP - 60000000) * 0.15
        PKP = 60000000
    End If
    Pajak = Pajak + PKP * 0.05

    HitungPPh21Tahunan = Pajak
End Function

Berikut penampakannya dalam Editor VBA:

Penjelasan Perhitungan Script

Fungsi HitungPPh21Tahunan(...) melakukan langkah-langkah berikut:

1. Biaya Jabatan = 5% dari penghasilan bruto, maksimum Rp 6.000.000 per tahun

2. PTKP ditentukan berdasarkan status:

• TK/0: Rp 54.000.000
• K/0: Rp 58.500.000
• K/1: Rp 63.000.000
• K/2: Rp 67.500.000
• K/3: Rp 72.000.000

3. PKP (Penghasilan Kena Pajak) = Bruto – Biaya Jabatan – Premi Asuransi – PTKP (dibulatkan ke bawah ribuan)

4. Pajak dihitung bertingkat berdasarkan tarif pada tabel di atas.

Dengan skrip ini, kamu tidak perlu menghitung secara manual setiap kali ada perubahan penghasilan. Dan sebagai contoh, berikut adalah tabel sederhana Kalkulator perhitungan pajak progresif PPh 21:

Cara Menggunakan Fungsi HitungPPh21Tahunan

1. Masuk ke Editor VBA
   Tekan Alt + F11 di Excel untuk membuka jendela editor VBA.
2. Masukkan Kode
   Pilih menu Insert > Module dan salin seluruh kode UDF di atas ke dalam modul tersebut.
3. Simpan File sebagai Macro-Enabled Workbook
   Simpan file Excel kamu dengan ekstensi .xlsm agar macro bisa berjalan dengan baik.
4. Gunakan Fungsi di Worksheet
   Misalnya, jika Jenis Pemotongan, Penghasilan Bruto, Status, Biaya Jabatan/Premi Asuransi berada di sel C3:C6, maka rumus berikut dapat digunakan:

   =HitungPPh21(C3; C4; C5; C6)

Fungsi ini akan secara otomatis menghitung persentase distribusi nilai siswa yang belum mencapai ketuntasan. Berikut hasilnya:

Contoh Kasus

Sebagai contoh, berikut adalah perhitungan pajak progresif PPh 21 dengan asumsi penghasilan bruto Rp5.100.000.000:

• Jenis Pemotongan: PPh 21 Tahunan (A1/A2)
• Penghasilan Bruto: Rp 5.100.000.000
• Status: TK/0
• Premi Asuransi: Rp 0 (diasumsikan tidak ada)

Contoh Perhitungan: Penghasilan Bruto Rp 5.100.000.000

Langkah 1: Hitung Biaya Jabatan
5% dari Rp 5.100.000.000 = Rp 255.000.000
Namun maksimum hanya Rp 6.000.000
Biaya Jabatan = Rp 6.000.000

Langkah 2: Tentukan PTKP (Status TK/0)
PTKP = Rp 54.000.000

Langkah 3: Hitung PKP (Penghasilan Kena Pajak)
PKP = Bruto – Biaya Jabatan – Premi – PTKP
= Rp 5.100.000.000 – Rp 6.000.000 – Rp 0 – Rp 54.000.000
= Rp 5.040.000.000
Dibulatkan ke ribuan = Rp 5.040.000.000

Perhitungan Pajak Progresif:

Total Pajak PPh 21 Terutang:

Rp 3.000.000 + Rp 28.500.000 + Rp 62.500.000 + Rp 1.350.000.000 + Rp 14.000.000 = Rp 1.458.000.000

Keunggulan Kalkulator Perhitungan Pajak Progresif PPh 21 Excel

• Otomatis dan bisa digunakan untuk banyak karyawan
• Akurat mengikuti ketentuan terbaru
• Dapat digunakan untuk pajak tahunan, bulanan, dan final
• Lebih cepat dibanding menghitung manual
• Dapat dikustomisasi untuk keperluan perusahaan

Kamu bisa menambahkan fitur seperti NIK karyawan, penghasilan lain, tunjangan, atau potongan lain untuk memperluas fungsinya.

Penutup

Dengan membuat kalkulator perhitungan pajak progresif PPh 21 otomatis di Excel, kamu bisa menyederhanakan proses yang sebelumnya kompleks. Baik untuk HRD perusahaan, pelaku UMKM, maupun akuntan freelance, alat ini akan menghemat waktu, meningkatkan akurasi, dan membantu mematuhi aturan perpajakan.

Jika kamu membutuhkan template siap pakai atau ingin custom sesuai kebutuhan bisnis, jangan ragu untuk menghubungi tim depotexcel.com. Kami siap bantu kembangkan solusi Excel otomatis untuk pekerjaanmu!

Download Template Gratis

Bagi Anda yang ingin mencoba teknik ini secara langsung, kami telah menyiapkan template gratis yang dirancang khusus untuk membantu Anda mempaktikkan Kalkulator Perhitungan Pajak Progresif PPh 21 Otomatis di Excel dengan VBA ini. File Excel bisa didownload melalui tautan berikut:

Atau juga jika ingin mempelajari langkah demi langkah secara visual, bisa kunjungi Youtube Channel Depot Excel. Di sana teman-teman akan melihat bagaimana rumusnya bekerja. Semoga bermanfaat!