3 Rumus Excel untuk Menghitung Data Berdasarkan Bulan dan Tahun

Dalam pengolahan data menggunakan Microsoft Excel, sering kali kita perlu menghitung data berdasarkan bulan dan tahun. Misalnya, Anda memiliki data transaksi penjualan harian, lalu ingin tahu berapa banyak transaksi yang terjadi di bulan tertentu pada tahun tertentu. Dengan bantuan beberapa rumus Excel, pekerjaan ini bisa dilakukan secara otomatis, cepat, dan akurat tanpa harus menghitung manual satu per satu.

Pada artikel ini kita akan membahas tiga cara berbeda untuk menghitung data berdasarkan bulan dan tahun, yaitu dengan menggunakan rumus COUNTIFS, SUMPRODUCT, dan FILTER. Masing-masing rumus memiliki kelebihan dan kekurangan, sehingga Anda bisa menyesuaikan dengan kebutuhan serta versi Excel yang digunakan.

Contoh tabel yang kita gunakan adalah sebagai berikut:

Dari tabel tersebut, kita ingin tahu berapa kali produk tertentu muncul pada bulan dan tahun tertentu. Misalnya, menghitung jumlah produk A pada Maret 2024. Berikut adalah 3 rumus Excel yang bisa dipakai.

1. Menggunakan COUNTIFS

Rumus pertama adalah:

=COUNTIFS($B$3:$B$27;">=1"&$F4&$G4;$B$3:$B$27;"<="&EOMONTH("1"&$F4&$G4;0);$C$3:$C$27;H$3)

Dan berikut hasilnya:

Penjelasan:

• COUNTIFS digunakan untuk menghitung jumlah data dengan banyak kriteria sekaligus.
• $B$3:$B$27 adalah rentang kolom yang berisi tanggal transaksi.
• ">=1"&$F4&$G4 berarti tanggal harus lebih besar atau sama dengan tanggal 1 di bulan dan tahun yang dipilih. Misalnya jika F4 berisi Mar dan G4 berisi 2024, maka hasilnya 01/03/2024.
• "<="&EOMONTH("1"&$F4&$G4;0) memastikan tanggal tidak melewati akhir bulan.
• $C$3:$C$27;H$3 digunakan untuk menyaring berdasarkan produk. Jadi hanya produk yang sesuai dengan H3 yang dihitung.

Kelebihan:

• Rumus ini fleksibel untuk data transaksi dalam jumlah besar.
• Bisa digunakan di semua versi Excel.

Dengan COUNTIFS, kita bisa menghitung data berdasarkan bulan dan tahun dengan cepat tanpa perlu rumus tambahan.

2. Menggunakan SUMPRODUCT

Rumus kedua adalah:

=SUMPRODUCT((TEXT($B$3:$B$27;"mmm")=$F11)*(YEAR($B$3:$B$27)=$G11)*($C$3:$C$27=H$10))

Dan berikut hasilnya:

Penjelasan:

• SUMPRODUCT digunakan untuk menjumlahkan hasil perkalian dari beberapa kondisi logika.
• TEXT($B$3:$B$27;"mmm")=$F11 berarti kita mengambil nama bulan dalam format singkatan (Jan, Feb, Mar, dst) dan membandingkannya dengan sel F11. Jika F11 berisi “Mar”, maka hanya baris dengan bulan Maret yang bernilai 1 (true).
• YEAR($B$3:$B$27)=$G11 memastikan data yang dihitung sesuai dengan tahun yang dipilih di sel G11.
• ($C$3:$C$27=H$10) membandingkan nama produk dengan sel H10.
• Hasil akhirnya adalah jumlah baris data yang sesuai dengan ketiga kriteria tersebut.

Kelebihan:

• Lebih sederhana dibaca karena langsung memisahkan bulan dengan fungsi TEXT dan tahun dengan fungsi YEAR.
• Cocok untuk Anda yang ingin hasil lebih cepat tanpa perlu menggunakan EOMONTH.

Dengan SUMPRODUCT, proses menghitung data berdasarkan bulan dan tahun menjadi lebih intuitif karena langsung membaca bulan dan tahun dari data tanggal.

3. Menggunakan FILTER + ROWS

Rumus ketiga adalah:

=IFERROR(ROWS(FILTER($B$3:$B$27;(TEXT($B$3:$B$27;"mmm")=$F18)*(YEAR($B$3:$B$27)=$G18)*($C$3:$C$27=H$17)));0)

Dan berikut hasilnya:

Penjelasan:

• FILTER berfungsi menyaring data sesuai kriteria yang diberikan.
• (TEXT($B$3:$B$27;"mmm")=$F18) memastikan bulan sesuai dengan nilai di F18.
• (YEAR($B$3:$B$27)=$G18) memastikan tahun sesuai.
• ($C$3:$C$27=H$17) menyaring berdasarkan produk.
• ROWS(...) menghitung berapa banyak baris hasil filter.
• IFERROR(...;0) digunakan agar jika tidak ada data, hasilnya tetap 0, bukan error #CALC!.

Kelebihan:

• Lebih modern dan rapi karena FILTER merupakan fungsi dinamis di Excel 365/2021.
• Bisa menampilkan data yang sesuai, bukan hanya menghitung jumlah.

Dengan rumus ini, menghitung data berdasarkan bulan dan tahun menjadi sangat praktis, terutama jika Anda menggunakan Excel versi terbaru.

Kesimpulan

Ada banyak cara untuk menghitung data berdasarkan bulan dan tahun di Excel.

• Jika ingin metode klasik yang bisa dipakai di semua versi Excel, gunakan COUNTIFS.
• Jika ingin lebih ringkas dengan logika sederhana, gunakan SUMPRODUCT.
• Jika menggunakan Excel 365/2021 dan ingin hasil fleksibel, gunakan FILTER dengan ROWS.

Dengan memahami tiga rumus ini, Anda bisa menyesuaikan mana yang paling sesuai untuk kebutuhan analisis data Anda. Mulai dari menghitung jumlah transaksi bulanan, memantau penjualan tahunan, hingga membuat laporan ringkas berdasarkan periode waktu tertentu, semuanya bisa dilakukan hanya dengan satu baris rumus.

Jadi, sekarang Anda tidak perlu bingung lagi. Gunakan salah satu dari tiga rumus di atas untuk menghitung data berdasarkan bulan dan tahun sesuai kebutuhan Anda.

Download Template Gratis

Bagi Anda yang ingin mencoba teknik ini secara langsung, kami telah menyiapkan template gratis yang dirancang khusus untuk membantu Anda mempraktikkan 3 Rumus Excel untuk Menghitung Data Berdasarkan Bulan dan Tahun ini. File Excel bisa didownload melalui tautan berikut:

Atau juga jika ingin mempelajari langkah demi langkah secara visual, bisa kunjungi Youtube Channel Depot Excel. Di sana teman-teman akan melihat bagaimana rumusnya bekerja. Semoga bermanfaat!