Cara Menghitung Umur Otomatis di Excel dengan Rumus VBA yang Mudah

Microsoft Excel adalah alat yang sangat populer untuk mengelola data, termasuk data pribadi seperti tanggal lahir. Salah satu kebutuhan umum pengguna Excel adalah menghitung umur otomatis di Excel berdasarkan tanggal lahir seseorang. Meskipun Excel memiliki rumus-rumus bawaan seperti DATEDIF, namun hasilnya terkadang kurang fleksibel, terutama jika kita ingin menampilkan hasil dalam format lengkap: tahun, bulan, dan hari.

Nah, pada artikel ini, kita akan membahas cara membuat fungsi kustom (User Defined Function atau UDF) yang bisa digunakan untuk menghitung umur otomatis di Excel dengan format yang lebih informatif dan mudah dipahami. Hasilnya akan terlihat seperti ini:

25 tahun 4 bulan 17 hari

Kenapa Harus Menggunakan VBA?

Rumus bawaan Excel seperti DATEDIF atau kombinasi YEAR, MONTH, dan DAY memang bisa digunakan, tapi seringkali rumit dan panjang. Dengan menggunakan VBA (Visual Basic for Applications), kita bisa membuat rumus sendiri yang lebih sederhana saat digunakan, misalnya:

=HitungUmur(A1; B1)

Fungsi ini akan secara otomatis menghitung umur berdasarkan tanggal lahir yang ada di sel A1, dan dibandingkan dengan tanggal hari ini (TODAY()).

Ini sangat bermanfaat jika kamu mengelola data seperti daftar siswa, karyawan, pasien, atau data penduduk, dan ingin menghitung umur otomatis di Excel secara cepat dan akurat.

Cara Membuat Fungsi HitungUmur di Excel

Sebagai contoh, kita akan menghitung umur dari orang-orang pada tabel di bawah ini:

Ikuti langkah berikut ini:

1. Tekan Alt + F11 untuk membuka jendela Visual Basic for Applications.
2. Klik Insert → Module.
3. Copy dan paste kode berikut:

Function HitungUmur(tanggalMulai As Variant, tanggalAkhir As Variant) As String
    Dim dtStart As Date, dtEnd As Date
    Dim tahun As Long, bulan As Long, hari As Long
    Dim tempDate As Date

    If Not IsDate(tanggalMulai) Or Not IsDate(tanggalAkhir) Then
        HitungUmur = "Input tidak valid"
        Exit Function
    End If

    dtStart = CDate(tanggalMulai)
    dtEnd = CDate(tanggalAkhir)

    If dtStart > dtEnd Then
        HitungUmur = "Rentang tidak valid"
        Exit Function
    End If

    tahun = DateDiff("yyyy", dtStart, dtEnd)
    If DateSerial(Year(dtStart) + tahun, Month(dtStart), Day(dtStart)) > dtEnd Then tahun = tahun - 1

    tempDate = DateAdd("yyyy", tahun, dtStart)
    bulan = DateDiff("m", tempDate, dtEnd)
    If DateAdd("m", bulan, tempDate) > dtEnd Then bulan = bulan - 1

    tempDate = DateAdd("m", bulan, DateAdd("yyyy", tahun, dtStart))
    hari = dtEnd - tempDate

    HitungUmur = tahun & " tahun " & bulan & " bulan " & hari & " hari"
End Function

Berikut tampilannya dalam

4. Simpan dan tutup jendela VBA (Ctrl + S, lalu Alt + Q).
5. Kembali ke Excel, dan gunakan rumusnya seperti ini:

=HitungUmur(C5; $D$2)

Dan berikut adalah hasilnya:

Keunggulan Rumus HitungUmur

Dengan fungsi ini, kamu bisa:

• Menampilkan hasil umur secara lengkap (tahun, bulan, hari).
• Meminimalisir kesalahan perhitungan manual.
• Membuat laporan yang lebih profesional.
• Menyederhanakan tampilan rumus, cukup dengan satu fungsi saja.

Tidak heran jika banyak pengguna Excel mencari solusi seperti ini untuk menghitung umur otomatis di Excel dalam proyek mereka.

Contoh Penggunaan dalam Kehidupan Nyata

1. Sekolah yang ingin menampilkan umur siswa di daftar hadir.
2. HRD yang perlu mengetahui umur karyawan secara cepat.
3. Lembaga kesehatan yang mencatat usia pasien.
4. Pendataan warga di instansi pemerintah.

Semua itu akan lebih mudah dengan fitur menghitung umur otomatis di Excel menggunakan fungsi HitungUmur ini.

Kesimpulan

Jika kamu sering bekerja dengan data tanggal lahir dan ingin menampilkan umur secara lengkap dalam format tahun, bulan, dan hari, maka fungsi HitungUmur berbasis VBA ini adalah solusi terbaik. Dibandingkan dengan rumus-rumus standar yang panjang dan rumit, UDF ini jauh lebih simpel dan efisien.

Cobalah sekarang juga dan rasakan kemudahan menghitung umur otomatis di Excel hanya dengan satu fungsi sederhana. Pastikan kamu menyimpan workbook sebagai Macro-Enabled Workbook (.xlsm) agar fungsi ini tetap bisa digunakan kapan saja.

Download Template Gratis

Bagi Anda yang ingin mencoba teknik ini secara langsung, kami telah menyiapkan template gratis yang dirancang khusus untuk membantu Anda mempaktikkan Cara Menghitung Umur Otomatis di Excel dengan Rumus VBA ini. File Excel bisa didownload melalui tautan berikut:

Atau juga jika ingin mempelajari langkah demi langkah secara visual, bisa kunjungi Youtube Channel Depot Excel. Di sana teman-teman akan melihat bagaimana rumusnya bekerja. Semoga bermanfaat!