2 Cara Membuat Jadwal Pertandingan Liga di Excel Secara Otomatis dengan LET

Membuat fixture pertandingan secara manual tentu memerlukan waktu yang cukup lama, apalagi jika jumlah klub yang digunakan cukup banyak. Untungnya, Excel modern kini memiliki fungsi dynamic array yang sangat powerful sehingga kita bisa membuat jadwal pertandingan otomatis tanpa VBA. Pada artikel lanjutan ini kita akan membahas secara lengkap tentang cara membuat jadwal pertandingan liga di Excel menggunakan rumus LET.

Tutorial ini merupakan lanjutan dari artikel sebelumnya tentang VBA Macro yang berjudul: Cara Membuat Jadwal Liga Otomatis di Excel Menggunakan VBA Macro. Bedanya, kali ini kita akan fokus menggunakan rumus Excel murni tanpa macro. Dengan memahami cara membuat jadwal pertandingan liga di Excel menggunakan fungsi LET, MAKEARRAY, HSTACK, dan VSTACK, Anda bisa membuat fixture pertandingan otomatis hanya dengan satu rumus.

Selain lebih praktis, cara membuat jadwal pertandingan liga di Excel ini juga sangat cocok untuk pengguna Excel 365 atau Excel 2024 yang sudah mendukung dynamic array. Hasilnya pun sangat rapi karena setiap tim hanya bermain satu kali setiap pekan.

Pada tutorial ini kita akan membahas 2 cara membuat jadwal pertandingan liga di Excel, yaitu:

1. Membuat jadwal pertandingan lengkap dalam format teks
2. Membuat jadwal pertandingan lengkap dengan kolom skor

Kedua metode tersebut sama-sama menggunakan sistem round robin sehingga semua tim akan saling bertemu kandang dan tandang.

Persiapan Data Klub

Sebelum mulai mempelajari cara membuat jadwal pertandingan liga di Excel, pertama-tama siapkan daftar klub terlebih dahulu. Kemudian masukkan nama klub pada range B3:B22 seperti berikut:

Pada tutorial ini:

• B2 digunakan sebagai header
• B3:B22 digunakan untuk nama klub
• Hasil fixture akan muncul mulai kolom D

Cara Pertama Membuat Jadwal Pertandingan Liga di Excel

Metode pertama dalam cara membuat jadwal pertandingan liga di Excel ini menghasilkan fixture dalam format teks seperti:

1    Arsenal vs Wolverhampton Wanderers
1    Aston Villa vs West Ham United

Rumus yang digunakan adalah:

=LET(
T;B3:B22;
N;ROWS(T);
R;N-1;
M;N/2;
X;DROP(T;1);
Y;TAKE(T;1);
ROT;LAMBDA(V;S;
IF(
S=0;
V;
VSTACK(
DROP(V;S);
TAKE(V;S)
)
)
);
HOME;MAKEARRAY(R*M;1;
LAMBDA(r;c;
LET(
wk;INT((r-1)/M);
gm;MOD(r-1;M)+1;
rot;ROT(X;wk);
IF(gm=1;Y;INDEX(rot;gm-1))
)
)
);
AWAY;MAKEARRAY(R*M;1;
LAMBDA(r;c;
LET(
wk;INT((r-1)/M);
gm;MOD(r-1;M)+1;
rot;ROT(X;wk);
INDEX(rot;N-gm)
)
)
);
WEEK1;ROUNDUP(SEQUENCE(R*M)/M;0);
PART1;HSTACK(WEEK1;HOME&" vs "&AWAY);
PART2;HSTACK(WEEK1+R;AWAY&" vs "&HOME);
VSTACK(PART1;PART2)
)

Penjelasan Rumus Pertama Secara Detail

Agar lebih mudah memahami cara membuat jadwal pertandingan liga di Excel, mari kita bahas rumus di atas satu per satu.

1. Menentukan Range Klub

T;B3:B22

Bagian ini digunakan untuk mengambil daftar klub.

2. Menghitung Jumlah Tim

N;ROWS(T)

Fungsi ROWS digunakan untuk menghitung jumlah klub. Jika ada 20 tim maka:

N = 20

3. Menghitung Jumlah Pekan

R;N-1

Karena menggunakan sistem round robin:

• 20 tim = 19 pekan

4. Menghitung Jumlah Pertandingan per Pekan

M;N/2

Jika ada 20 tim:

20 ÷ 2 = 10 pertandingan

5. Memisahkan Tim Pertama

X;DROP(T;1)
Y;TAKE(T;1)

Bagian ini sangat penting dalam cara membuat jadwal pertandingan liga di Excel.

• TAKE mengambil tim pertama
• DROP mengambil sisa tim

Tim pertama akan dibuat tetap, sedangkan tim lainnya akan diputar.

6. Membuat Fungsi Rotasi

ROT;LAMBDA(V;S;
IF(
S=0;
V;
VSTACK(
DROP(V;S);
TAKE(V;S)
)
)
)

Ini merupakan inti dari sistem round robin. Fungsi tersebut digunakan untuk memutar susunan tim setiap pekan.

7. Membuat Tim Home

HOME;MAKEARRAY(R*M;1;
LAMBDA(r;c;
LET(
wk;INT((r-1)/M);
gm;MOD(r-1;M)+1;
rot;ROT(X;wk);
IF(gm=1;Y;INDEX(rot;gm-1))
)
)
)

Bagian ini digunakan untuk menentukan tim home. Fungsi MAKEARRAY akan membuat daftar pertandingan secara otomatis.

8. Membuat Tim Away

AWAY;MAKEARRAY(R*M;1;
LAMBDA(r;c;
LET(
wk;INT((r-1)/M);
gm;MOD(r-1;M)+1;
rot;ROT(X;wk);
INDEX(rot;N-gm)
)
)
)

Bagian ini digunakan untuk menentukan tim away.

9. Membuat Nomor Pekan

WEEK1;ROUNDUP(SEQUENCE(R*M)/M;0)

Fungsi ini akan menghasilkan:

1
1
1
1
2
2
2

Sehingga setiap 10 pertandingan berada pada pekan yang sama.

10. Membuat Putaran Kedua

PART2;HSTACK(WEEK1+R;AWAY&" vs "&HOME)

Bagian ini digunakan untuk membuat pertandingan kandang dan tandang. Home dan away otomatis dibalik.

Hasil Akhir Rumus Pertama

Hasil akhir dari cara membuat jadwal pertandingan liga di Excel pertama ini adalah:

Metode ini sangat cocok jika Anda hanya ingin membuat fixture pertandingan sederhana.

Cara Kedua Membuat Jadwal Pertandingan Liga di Excel

Metode kedua dalam cara membuat jadwal pertandingan liga di Excel menghasilkan fixture yang lebih profesional karena sudah memiliki kolom skor. Hasil akhirnya seperti berikut:

Week	Home	HG	AG	Away
1	Arsenal			Wolverhampton Wanderers
1	Aston Villa			West Ham United
1	Bournemouth			Tottenham Hotspur

Rumus yang digunakan adalah:

=LET(
T;B3:B22;
N;ROWS(T);
R;N-1;
M;N/2;
X;DROP(T;1);
Y;TAKE(T;1);

ROT;LAMBDA(V;S;
IF(
S=0;
V;
VSTACK(
DROP(V;S);
TAKE(V;S)
)
)
);

HOME;MAKEARRAY(R*M;1;
LAMBDA(r;c;
LET(
wk;INT((r-1)/M);
gm;MOD(r-1;M)+1;
rot;ROT(X;wk);
IF(gm=1;Y;INDEX(rot;gm-1))
)
)
);

AWAY;MAKEARRAY(R*M;1;
LAMBDA(r;c;
LET(
wk;INT((r-1)/M);
gm;MOD(r-1;M)+1;
rot;ROT(X;wk);
INDEX(rot;N-gm)
)
)
);

WEEK;ROUNDUP(SEQUENCE(R*M)/M;0);

EMPTYCOL;MAKEARRAY(ROWS(HOME);1;LAMBDA(r;c;""));

VSTACK(
HSTACK(WEEK;HOME;EMPTYCOL;EMPTYCOL;AWAY);
HSTACK(WEEK+R;AWAY;EMPTYCOL;EMPTYCOL;HOME)
)
)

Penjelasan Rumus Kedua

Secara umum, cara membuat jadwal pertandingan liga di Excel kedua ini memiliki logika yang sama dengan rumus pertama. Perbedaannya terdapat pada bagian berikut:

EMPTYCOL;MAKEARRAY(ROWS(HOME);1;LAMBDA(r;c;""))

Bagian ini digunakan untuk membuat kolom kosong. Kolom kosong tersebut nantinya dipakai untuk:

• HG = Home Goal
• AG = Away Goal

Mengapa Menggunakan MAKEARRAY untuk Kolom Kosong?

Banyak pengguna Excel mengalami error #N/A ketika mencoba menggunakan:

""

langsung di dalam HSTACK. Karena itu digunakan:

MAKEARRAY(ROWS(HOME);1;LAMBDA(r;c;""))

agar jumlah baris kosong sama dengan jumlah pertandingan. Ini merupakan salah satu trik penting dalam cara membuat jadwal pertandingan liga di Excel menggunakan dynamic array.

Hasil Akhir Rumus Kedua

Hasil akhir dari metode kedua adalah:

Metode ini lebih cocok digunakan untuk:

• kompetisi sepak bola
• futsal
• esport
• turnamen sekolah
• liga komunitas

karena kolom skor bisa langsung digunakan.

Kelebihan Menggunakan Rumus LET untuk Fixture Liga

Ada banyak keuntungan menggunakan cara membuat jadwal pertandingan liga di Excel dengan fungsi LET.

1. Tanpa VBA; Tidak perlu macro sehingga file lebih aman.
2. Otomatis; Fixture langsung muncul hanya dengan satu rumus.
3. Dinamis; Jika daftar tim berubah, jadwal otomatis ikut berubah.
4. Mendukung Home Away; Semua pertandingan kandang dan tandang dibuat otomatis.
5. Tidak Ada Bentrok Jadwal; Setiap tim hanya bermain satu kali setiap pekan.

Kekurangan Metode Rumus Dynamic Array

Meski sangat powerful, metode ini juga memiliki kekurangan.

1. Tidak Bisa Diedit Sebagian; Karena hasilnya berupa spill array.
2. Membutuhkan Excel Modern; Fungsi seperti:

• LET
• MAKEARRAY
• VSTACK
• HSTACK

hanya tersedia di Excel 365 dan Excel 2024.

Kesimpulan

Cara membuat jadwal pertandingan liga di Excel ternyata bisa dilakukan tanpa VBA menggunakan fungsi dynamic array modern seperti LET, MAKEARRAY, HSTACK, dan VSTACK.

Pada tutorial ini kita telah mempelajari 2 cara membuat jadwal pertandingan liga di Excel, yaitu metode fixture teks sederhana dan metode fixture lengkap dengan kolom skor.

Kedua metode tersebut sama-sama menggunakan sistem round robin sehingga semua tim dapat saling bertemu tanpa bentrok jadwal.

Dengan memahami cara membuat jadwal pertandingan liga di Excel, Anda dapat membuat fixture kompetisi sepak bola, futsal, esport, maupun turnamen sekolah secara otomatis hanya dengan satu rumus.

Semoga tutorial cara membuat jadwal pertandingan liga di Excel ini bermanfaat dan selamat mencoba!

Download Template Gratis

Bagi Anda yang ingin mencoba teknik ini secara langsung, kami telah menyiapkan template gratis yang dirancang khusus untuk membantu Anda mempraktikkan 2 Cara Membuat Jadwal Pertandingan Liga di Excel Secara Otomatis dengan Rumus LET ini. File Excel bisa didownload melalui tautan berikut:

Atau juga jika ingin mempelajari langkah demi langkah secara visual, bisa kunjungi Youtube Channel Depot Excel. Di sana teman-teman akan melihat bagaimana rumusnya bekerja. Semoga bermanfaat!

—