3 Cara Menghitung Komisi Penjualan di Excel untuk Semua Versi Excel

Dalam dunia penjualan, pemberian komisi merupakan bentuk penghargaan kepada tenaga penjual atas pencapaian target penjualan. Untuk itu, memahami cara menghitung komisi penjualan di Excel menjadi keterampilan penting bagi staf keuangan, HRD, hingga manajer penjualan.

Artikel ini membahas 3 cara menghitung komisi penjualan di Excel, yang dapat digunakan untuk berbagai versi Excel: dari versi lama hingga Excel terbaru (Excel 365/2024). Kami juga akan membahas masing-masing rumus yang digunakan secara rinci agar Anda mudah mengikutinya.

Contoh Kasus Komisi Penjualan

Misalkan sebuah perusahaan memiliki ketentuan pemberian komisi berdasarkan nilai omset seperti pada tabel berikut:

1. Cara Menghitung Komisi Penjualan di Excel Versi Lama (Sebelum Excel 2021)

Jika Anda menggunakan Excel 2010, 2013, atau 2016, Anda bisa memakai kombinasi fungsi LOOKUP dan SMALL:

=C9*LOOKUP(C9;SMALL($B$3:$B$6;{1\2\3\4});SMALL(C$3:C$6;{1\2\3\4}))

Dan berikut hasilnya:

Penjelasan Rumus:

• C9: nilai omset yang akan dicari prosentase komisinya.
• SMALL($B$3:$B$6;{1\2\3\4}): mengambil seluruh nilai dari kolom batas omset (diurutkan).
• SMALL(C$3:C$6;{1\2\3\4}): mengambil seluruh persentase komisi sesuai kolom produk.
• LOOKUP(C9;...;...): mencari nilai komisi yang sesuai dengan omset.
• Hasil dikalikan dengan C9 untuk mendapatkan nilai komisinya.

Kelebihan: Kompatibel dengan versi lama
Kekurangan: Rumus agak sulit dibaca dan tidak fleksibel jika baris bertambah.

2. Cara Menghitung Komisi Penjualan di Excel 2021 Menggunakan LET

Excel 2021 memperkenalkan fungsi LET yang memungkinkan Anda memberi nama pada bagian rumus, sehingga rumus menjadi lebih ringkas dan mudah dibaca.

=LET(
  omzet; C9;
  batas; $B$3:$B$6;
  persen; C$3:C$6;
  omzet * LOOKUP(omzet; batas; persen)
)

Dan berikut hasilnya:

Penjelasan Rumus:

• LET mendefinisikan variabel omzet, batas, dan persen.
• Fungsi LOOKUP mencari nilai omzet pada batas dan mengambil nilai persen yang sesuai.
• Rumus menjadi jauh lebih bersih dan bisa disalin ke kolom atau baris lain dengan cepat.

Kelebihan:

• Lebih mudah dibaca
• Mudah dirawat dan dimodifikasi
• Cocok untuk Excel 2021 ke atas

3. Cara Menghitung Komisi Penjualan di Excel Versi 2024 atau Office 365 Menggunakan LAMBDA

Excel versi terbaru (Office 365 / 2024) mendukung LAMBDA, fungsi yang memungkinkan kita membuat rumus seperti fungsi buatan sendiri (custom function/UDF).

Ada 2 cara memperlakukan fungsi LAMBDA ini yaitu dengan menuliskannya langsung di sel yang akan dijadikan output dan atau menjadikannya sebagai custom fuction dengan meletakkannya di Name Manager.

Jika Anda ingin meletakkannya langsung di sel, misalnya di sel F9 sesuai contoh tabel, maka gunakan rumus:

=LAMBDA(omzet; batas; persen; omzet * LOOKUP(omzet; batas; persen))(C9; $B$3:$B$6; C$3:C$6)

Dan berikut hasilnya:

Penjelasan Rumus:

• LAMBDA(...): mendefinisikan parameter: omzet, batas, persen.
• Kemudian, rumus dijalankan dengan nilai yang dimasukkan setelah penutup ).
• Fungsinya sama dengan LET, namun lebih fleksibel untuk dijadikan fungsi khusus di workbook.

Atau Anda bisa juga membuat fungsi khusus (custom function/UDF) bernama Komisi. Caranya:

1. Buka Excel

• Pastikan Anda menggunakan Excel 365 atau Excel 2024.

2. Buka Name Manager

• Klik Formulas > Name Manager
• Atau tekan shortcut: Ctrl + F3

3. Klik New (Baru)

• Di jendela Name Manager, klik tombol New.

4. Isi Kolom Berikut:

• Name: beri nama fungsi, misalnya Komisi
• Refers to: isikan rumus LAMBDA, contoh: =LAMBDA(omzet; batas; persen; omzet * LOOKUP(omzet; batas; persen))

5. Klik OK, lalu tutup Name Manager.

Cara Menggunakannya di Sel Excel

Setelah dipasang, Anda cukup memanggilnya seperti fungsi biasa:

=Komisi(C9; $B$3:$B$6; C$3:C$6)

• C9 adalah omset
• $B$3:$B$6 adalah kolom batas omset
• C$3:C$6 adalah persen komisi

Dan berikut hasilnya:

Kelebihan:

• Elegan dan profesional
• Dapat digunakan ulang
• Bisa digunakan sebagai UDF (User Defined Function) internal Excel

Kesimpulan

Menghitung komisi penjualan di Excel bisa dilakukan dengan cara yang berbeda tergantung pada versi Excel yang Anda gunakan. Berikut rangkumannya:

Dengan memahami cara menghitung komisi penjualan di Excel secara bertahap, Anda dapat memilih rumus yang paling cocok untuk kebutuhan kantor atau usaha Anda.

Download Template Gratis

Bagi Anda yang ingin mencoba teknik ini secara langsung, kami telah menyiapkan template gratis yang dirancang khusus untuk membantu Anda mempraktikkan 3 Cara Menghitung Komisi Penjualan di Excel untuk Semua Versi Excel ini. File Excel bisa didownload melalui tautan berikut:

Atau juga jika ingin mempelajari langkah demi langkah secara visual, bisa kunjungi Youtube Channel Depot Excel. Di sana teman-teman akan melihat bagaimana rumusnya bekerja. Semoga bermanfaat!

—

Tags: cara menghitung komisi penjualan di Excel, rumus komisi penjualan Excel otomatis, menghitung komisi berdasarkan omzet, lookup komisi Excel, fungsi LET di Excel, fungsi LAMBDA Excel, contoh perhitungan komisi Excel, membuat sistem komisi penjualan otomatis, cara hitung bonus dan komisi Excel, template Excel komisi penjualan.

—