Panduan Lengkap dan Contoh Pembukuan Koperasi Merah Putih Part 1

Dalam mengelola keuangan koperasi simpan pinjam, sangat penting untuk memiliki sistem pembukuan yang terstruktur dan rapi. Salah satu cara terbaik untuk melakukannya adalah dengan menggunakan Microsoft Excel. Dalam artikel ini, kita akan membahas contoh pembukuan koperasi Merah Putih, yang mencakup pembuatan kode akun, jurnal umum, dan buku besar. Dengan penjelasan formula Excel dan kode VBA, Anda dapat menerapkannya langsung ke dalam sistem koperasi Anda.

1. Struktur Dasar Pembukuan Koperasi

Contoh pembukuan koperasi Merah Putih biasanya dimulai dengan tiga komponen utama:

• Kode Akun: Digunakan untuk mengelompokkan transaksi berdasarkan jenis akun (misalnya: kas, bank, pinjaman, simpanan).
• Jurnal Umum (JU): Mencatat semua transaksi harian secara kronologis.
• Buku Besar (BB): Merangkum transaksi berdasarkan akun untuk menghasilkan saldo akhir.

2. Menyusun Kode Akun

Pada sheet Akun, daftar kode akun disusun dalam kolom:

• Kolom B: Kode Akun (misal: 1-101)
• Kolom C: Nama Akun (misal: Bank)
• Kolom D: Pos Saldo (D untuk Debet atau K untuk Kredit)
• Kolom E: Pos Laporan (N untuk Neraca dan L untuk Laba Rugi)
• Kolom F & G: Saldo Awal

Dalam contoh pembukuan koperasi Merah Putih, penggunaan kode akun yang konsisten sangat penting agar laporan keuangan tetap akurat.

3. Jurnal Umum (JU) dengan Validasi Otomatis

Untuk mencegah kesalahan input, digunakan validasi data otomatis berbasis macro VBA. Berikut adalah script yang digunakan:

Sub BuatDropdownTanpaKosong()
    Dim wsSumber As Worksheet, wsTujuan As Worksheet, wsTujuan2 As Worksheet
    Dim rngSumber As Range, sel As Range
    Dim daftarUnik As Collection
    Dim hasilValidasi As String
    Dim i As Long

    Set wsSumber = ThisWorkbook.Sheets("Akun")
    Set wsTujuan = ThisWorkbook.Sheets("JU")
    Set wsTujuan2 = ThisWorkbook.Sheets("BB") ' Tambahan sheet tujuan kedua
    Set rngSumber = wsSumber.Range("C3:C45")
    Set daftarUnik = New Collection

    On Error Resume Next
    For Each sel In rngSumber
        If Trim(sel.Value) <> "" Then
            daftarUnik.Add sel.Value, CStr(sel.Value)
        End If
    Next sel
    On Error GoTo 0

    If daftarUnik.Count = 0 Then
        MsgBox "Tidak ada data yang bisa digunakan!", vbExclamation
        Exit Sub
    End If

    ' Gabungkan semua item ke satu string dipisahkan koma
    hasilValidasi = ""
    For i = 1 To daftarUnik.Count
        hasilValidasi = hasilValidasi & daftarUnik(i) & ","
    Next i

    ' Hapus koma terakhir
    If Right(hasilValidasi, 1) = "," Then
        hasilValidasi = Left(hasilValidasi, Len(hasilValidasi) - 1)
    End If

    ' Terapkan data validation ke JU!E3:E24
    With wsTujuan.Range("E6:E27").Validation
        .Delete
        .Add Type:=xlValidateList, AlertStyle:=xlValidAlertStop, Operator:= _
            xlBetween, Formula1:=hasilValidasi
        .IgnoreBlank = True
        .InCellDropdown = True
        .ShowInput = True
        .ShowError = True
    End With

    ' Terapkan juga ke BB!D5
    With wsTujuan2.Range("D5").Validation
        .Delete
        .Add Type:=xlValidateList, AlertStyle:=xlValidAlertStop, Operator:= _
            xlBetween, Formula1:=hasilValidasi
        .IgnoreBlank = True
        .InCellDropdown = True
        .ShowInput = True
        .ShowError = True
    End With

    MsgBox "Data validasi berhasil diterapkan ke JU!E6:E27 dan BB!D5 tanpa sel kosong!", vbInformation
End Sub

Penjelasan:

• Validasi Data dibuat dari daftar unik nama akun yang tidak kosong.
• Dropdown diterapkan pada kolom jurnal umum dan buku besar agar pengguna hanya bisa memilih akun yang tersedia.
• Ini memastikan bahwa semua data yang dimasukkan pada sheet JU dan BB berasal dari daftar yang sah.

Berikut hasilnya:

Dan untuk memanggil kode akun di kolom D dari sheet “Akun”, di sel D6 gunakan rumus:

=XLOOKUP(E6; Akun!$C$3:$C$45;Akun!$B$3:$B$45;"";0)

4. Rumus Buku Besar (BB)

Contoh pembukuan koperasi Merah Putih menjadi lebih kuat dengan penggunaan rumus yang dinamis. Berikut ini beberapa rumus penting di sheet BB:

a. Mengambil Kode dan Posisi Akun

D4: =XLOOKUP(D5; Akun!$C$3:$C$45; Akun!$B$3:$B$45; ""; 0)
D6: =XLOOKUP(D5; Akun!$C$3:$C$45; Akun!$D$3:$D$45; ""; 0)
D7: =XLOOKUP(D5; Akun!$C$3:$C$45; Akun!$E$3:$E$45; ""; 0)

• D4 menampilkan Kode Akun berdasarkan Nama Akun.
• D6 menampilkan Posisi Saldo (D/K).
• D7 menampilkan Pos Laporan.

b. Menghitung Saldo Akhir

G4: =IF($D$4="";"";IF($D$6="D";G7+G6-G5;G7-G6+G5))
G5: =SUBTOTAL(9;E11:E30)  'Jumlah Debet
G6: =SUBTOTAL(9;F11:F30)  'Jumlah Kredit
G7: =LOOKUP(2;1/(ISNUMBER(G11:G30));G11:G30)  'Saldo Terakhir

• Rumus ini menghitung saldo akhir berdasarkan posisi saldo awal (debet/kredit).
• Gunakan SUBTOTAL(9;...) untuk menjumlahkan data yang mungkin terfilter.

c. Saldo Awal Akun

G10: =SUM(XLOOKUP(D4; Akun!B3:B45; Akun!E3:F45))

• Mengambil saldo awal dari sheet Akun berdasarkan Kode Akun.

5. Fungsi UDF: AmbilTanggalTerdekat

Untuk menyesuaikan tanggal transaksi dengan akun yang dipilih, digunakan UDF (User Defined Function) bernama AmbilTanggalTerdekat. Berikut adalah kodenya:

Function AmbilTanggalTerdekat(namaAkun As String, rngAkun As Range, rngTanggal As Range, urutanKe As Long) As Variant
    Dim arrAkun As Variant, arrTgl As Variant
    Dim i As Long, hitung As Long
    Dim posBaris As Long

    arrAkun = rngAkun.Value
    arrTgl = rngTanggal.Value

    hitung = 0
    posBaris = 0

    For i = 1 To UBound(arrAkun, 1)
        If arrAkun(i, 1) = namaAkun Then
            hitung = hitung + 1
            If hitung = urutanKe Then
                posBaris = i
                Exit For
            End If
        End If
    Next i

    If posBaris = 0 Then
        AmbilTanggalTerdekat = ""
        Exit Function
    End If

    If arrTgl(posBaris, 1) <> "" Then
        AmbilTanggalTerdekat = arrTgl(posBaris, 1)
    Else
        For i = posBaris - 1 To 1 Step -1
            If arrTgl(i, 1) <> "" Then
                AmbilTanggalTerdekat = arrTgl(i, 1)
                Exit Function
            End If
        Next i
        AmbilTanggalTerdekat = ""
    End If
End Function

Digunakan dalam sel seperti:

C11: =AmbilTanggalTerdekat($D$4; JU!$D$6:$D$27; JU!$B$6:$B$27; ROW(A1))
D11: =AmbilTanggalTerdekat($D$4; JU!$D$6:$D$27; JU!$C$6:$C$27; ROW(A1))

6. Menampilkan Debet dan Kredit Per Transaksi

E11: =IFERROR(FILTER(JU!F6:G27; JU!D6:D27=D4); "")

• Menyaring nilai debet dan kredit dari jurnal umum untuk akun yang sedang dianalisis di buku besar.

G11: =IF(COUNTA(E11:F11)=0; ""; IF($D$6="D"; G10 + E11 - F11; G10 - E11 + F11))

• Menghitung saldo berjalan per baris transaksi dalam buku besar.

Dan berikut hasil akhirnya:

7. Contoh Penerapan: Pembukuan Koperasi Merah Putih

Tabel buku besar di sheet BB menggambarkan aktivitas akun Bank (1-101) pada Juli 2025. Dalam contoh ini, tercatat:

• Penerimaan simpanan pokok, sukarela, dan modal anggota.
• Pengeluaran untuk pinjaman, gaji, dan kebutuhan operasional.

Contoh pembukuan koperasi Merah Putih ini sangat cocok untuk koperasi skala kecil dan menengah yang ingin menerapkan prinsip akuntansi dengan alat yang sederhana namun efektif.

Untuk membuat Neraca Saldo, Laba Rugi dan Neraca akan dibahas di artikel berikutnya.

Kesimpulan

Dengan penerapan kode akun, jurnal umum terstruktur, dan buku besar otomatis, contoh pembukuan koperasi Merah Putih ini memberikan gambaran yang jelas dan profesional mengenai pengelolaan keuangan koperasi. Anda dapat memodifikasi rumus dan VBA untuk menyesuaikan dengan kebutuhan koperasi masing-masing.

Beberapa manfaat utama dari sistem ini:

• Memudahkan audit internal.
• Menjaga akurasi laporan keuangan.
• Meningkatkan transparansi pengelolaan dana anggota.

Jika Anda sedang mencari contoh pembukuan koperasi Merah Putih yang bisa langsung digunakan, sistem ini layak untuk dicoba dan dikembangkan lebih lanjut.

Penutup

Semoga panduan dan contoh pembukuan koperasi Merah Putih ini membantu Anda dalam membuat sistem pembukuan yang lebih efektif dan efisien. Jangan lupa untuk menyimpan file Excel Anda secara berkala dan lakukan backup rutin agar data tidak hilang.

Jika Anda memiliki pertanyaan atau ingin file template lengkap dari contoh pembukuan koperasi Merah Putih ini, jangan ragu untuk menghubungi kami atau tinggalkan komentar di bawah!

Download Template Gratis

Bagi Anda yang ingin mencoba teknik ini secara langsung, kami telah menyiapkan template gratis yang dirancang khusus untuk membantu Anda mempraktikkan Panduan Lengkap dan Contoh Pembukuan Koperasi Merah Putih Part 1 ini. File Excel bisa didownload melalui tautan berikut:

Atau juga jika ingin mempelajari langkah demi langkah secara visual, bisa kunjungi Youtube Channel Depot Excel. Di sana teman-teman akan melihat bagaimana rumusnya bekerja. Semoga bermanfaat!

—

Tags: contoh pembukuan koperasi merah putih, pembukuan koperasi simpan pinjam, buku besar koperasi, jurnal umum koperasi, kode akun koperasi, excel koperasi simpan pinjam, laporan keuangan koperasi,
rumus excel pembukuan koperasi, template pembukuan koperasi, cara membuat pembukuan koperasi, pembukuan sederhana dengan excel, macro excel koperasi, vba excel pembukuan, laporan keuangan bulanan koperasi, tutorial excel koperasi.

—